Jüdische Sagen

"Computer" heißt wörtlich übersetzt "Rechner" und deshalb wäre es ja jetzt auch Zeit, ein Programm auch einmal etwas ausrechnen zu lassen. Denn Rechnen ist nicht nur etwas für Mathematik-Programme (die manchen von uns vielleicht nur wenig interessieren) sondern vor allem auch etwas, was für Computerspiele gebraucht wird. Das merkt man schon daran, dass viele neue Computerspiele nach immer schnellerer Computer-Hardware und Prozessor-Leistung verlangen.

Zum Rechnen muss das Programm drei Dinge tun:

• Die Zahlen, die verrechnet werden müssen, müssen eingelesen werden (das machen wir jetzt zunächst über die Tastatur; einlesen kann man Werte natürlich auch über die Maus, den Joystick oder Lenkrad und Gaspedal für Autorennspiele).
• Die Zahlen müssen zu einem Ergebnis verrechnet werden.
• Das Ergebnis der Verrechnung muss auf der Benutzeroberfläche ausgegeben werden.

Arbeiten mit eigenen Variablen

Bisher haben wir nur die Eigenschaften von bestimmten Komponenten geändert bzw. Dinge darin gespeichert, etwa die Beschriftung eines Buttons. Bei komplizierteren Programmen müssen wir aber auch andere Dinge speichern, Dinge die nicht unbedingt jeder gleich sehen muss. Hierfür gibt es so selbst definierte Variablen.

Jede Variable hat drei wichtige Punkte:

• Name: Jede Variable hat einen eindeutigen Namen, über den sie im Programm angesprochen werden kann.
• Typ: Wie schon bei den Eigenschaften von Komponenten haben auch Variablen verschiedene Typen: ganze Zahlen (integer), reelle Zahlen (real oder double), Zeichenketten (string) usw.
• Wert: In der Variablen gespeichert ist zu jeder Zeit ein ganz bestimmter Wert. Bei einer Variable vom Typ integer könnte das z.B. die Zahl 42 sein.

Um dem Computer mitzuteilen, dass es eine Variable zahl vom Typ integer geben soll, muss man die Variable deklarieren. Die Liste der Variablen eines Programms findet sich hinter dem Stichwort var im Programm. Dort ist in unserem Fall bereits die Variable Form1 deklariert. Dies ergänzen wir nun um unsere eigene Variable zahl

var Form1 : TForm1;
    zahl : integer;

Wie bei den Eigenschaften auch wird den Variablen im eigentlichen Programmtext zwischen begin und end; ein Wert über den ":="-Operator zugewiesen, etwa

zahl:=42;

Ein anschauliches Bild für die Variablen in einem Computerprogramm ist ein Schubladenschrank in der Küche. Der Wert einer Variable entspräche Inhalt einer solchen Schublade, der Name wäre etwa ein Etikett auf der Schublade. Um den Vergleich -- wenn auch etwas hinkend -- weiterzuführen, könnte der Typ der Variablen soetwas wie ein Schubladeneinsatz sein. Es gibt solche Einsätze für Dessertlöffel, aber z.B. auch für Münzgeld.

Einlesen von Integer-Variablen

Die Anweisung zahl:=42; weist der Variablen einen festen Wert, hier die 42 zu. Häufig braucht man jedoch Variablen, deren Wert vom Benutzer während der Laufzeit des Programms eingegeben werden, etwa über eine TEdit-Komponente. Gibt ein Benutzer über eine solche Kompoente eine Zahl ein, steht sie zunächst als Zeichenkette in der Eigenschaft Text. Aus dieser Zeichenkette z.B. in Edit1.Text muss jetzt eine "richtige" Zahl (z.B. vom Typ integer) werden.

Das besorgt der Befehl StrToInt:

a:=StrToInt(Edit1.Text);

Diese Zeile sorgt dafür, dass der Integer-Variablen a der Wert zugewiesen wird, die der Benutzer in das Edit-Feld Edit1 geschrieben hat.

Rechnen mit Integer-Variablen

Nehmen wir an, wir hätten drei Integer-Variablen, a,b und c. Das Programm soll nun die Summe der Werte in a und b ausrechnen; das Ergebnis soll in der Variablen c gespeichert werden.

Dies erreicht man wieder mit einem Zuweisungsbefehl mit dem stilisierten Pfeil nach links:

c := a+b;

Natürlich gibt es neben der Addition von Integer-Zahlen auch andere Rechenoperationen:

Rechenoperation	Rechenzeichen in der Sprache Pascal	Beispiel
Addition	+	c:=a+b;
Subtraktion	-	c:=a-b;
Multiplikation	*	c:=a*b;
(ganzzahlige) Division	div	c:=a div b;
Rest der (ganzzahligen) Division	mod	c:=a mod b;

Die ganzzahlige Division ist die Division, die die meisten von uns aus der Grundschule kennen:

$34 : 5 = 6 \text{ Rest } 4$

Den Wert "6" würde dann die Rechenoperation 34 div 5 liefern, den Wert "4" die Operation 34 mod 5.

Ausgabe von Integer-Variablen

Bisher steht das Ergebnis nur in der Variable c. Der Benutzer des Programms sieht davon gar nichts. Der Wert muss noch irgendwie auf der Oberfläche erscheinen. Eine Möglichkeit dazu wäre, die Zahl in ein weiteres Edit-Feld zu schreiben:

Edit3.Text:=IntToStr(c);

Hintergrund: Der Inhalt von Edit-Feldern sind Zeichenketten (engl.: string). Damit eine Integer-Variable in einem Edit-Feld angezeigt werden kann, muss sie in einen solchen String umgewandelt werden. Das erledigt der Befehl IntToStr(...).

Das ganze Programm zum Rechnen mit Integer-Zahlen

Das folgende Programm funktioniert, wenn es auf der Oberfläche die Komponenten Edit1, Edit2 und Button1 gibt.

unit zahlen_main;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs, StdCtrls;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end; 

var
  Form1: TForm1; 
  a : integer;  // wir erfinden eine Zahlen-Variable a
  b : integer;  // wir erfinden eine Zahlen-Variable b
  c : integer;  // wir erfinden eine Zahlen-Variable c

implementation

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
a:=StrToInt(Edit1.Text);  // belege die Variablen
b:=StrToInt(Edit2.Text);  // mit den Inhalten der Edit-Felder

c:=a+b; // Addiere a und b und weise den Wert der Variable c zu

Edit3.Text:=IntToStr(c);

end;

initialization
  {$I zahlen_main.lrs}

end.

Arbeiten mit Reellen Zahlen

Das Arbeiten mit reellen Zahlen vom Typ real oder double funktioniert sehr ähnlich, mit ein paar kleinen Unterschieden. Zunächst einmal muss man statt integer natürlich double als Typbezeichnung verwenden.

Statt IntToStr und StrToInt werden hier der Befehl StrToFloat und der sehr mächtige Formatierungsbefehl format verwendet.

Die Zeile

Edit3.Text:=format('%5.2f',[c]);

sorgt dafür, dass die double-Variable c in das Edit-Feld geschrieben wird, dass sie insgesamt 5 Stellen und 2 Nachkommastellen hat.

procedure TForm1.Button1Click(Sender: TObject);
begin
a:=StrToFloat(Edit1.Text);  // belege die Variablen
b:=StrToFloat(Edit2.Text);  // mit den Inhalten der Edit-Felder

c:=a+b; // Addiere a und b und weise den Wert der Variable c zu

Edit3.Text:=format('%5.2f',[c]);

end;

Weitere Rechenoperationen für reelle Zahlen sind:

Rechenoperation	Rechenzeichen in der Sprache Pascal
Quadratwurzel-Funktion	sqrt(x)
Exponentialfunktion	exp(x)
Sinus-Funktion	sin(x)
Cosinus-Funktion	cos(x)
Tangens	tan(x)
Natürlicher Logarithmus	ln(x)
Kaufmännisches Runden	round(x)
Abrunden auf die nächstkleinere ganze Zahl	trunc(x)

Neben diesen mathematischen Funktionen gibt es noch jede Menge andere in Lazarus. Um diese jedoch verwenden zu können, muss in der Liste der so genannten Software-Bibliotheken noch die Bibliothek Math angegeben werden:

uses Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs, StdCtrls, Math;

Rechenoperation	Funktion in der Sprache Pascal
Umkehrfunktionen von trigonometrischen Funktionen	arcsin(x), arccos(x)
Logarithmus zur Basis 10	log10(x)
Logarithmus zur Basis 2	log2(x)
Logarithmus zu beliebiger Basis	logn(basis,x)
Beliebige Potenz	power(basis,exponent)
Umrechnung von Bogenmaß nach Gradmaß	radtodeg(x)
Umrechnung von Gradmaß nach Bogenmaß	degtorad(x)

Wichtig zu wissen ist bei den trigonometrischen Funktionen, dass sie immer von Angaben im Bogenmaß (statt 360° also $2\pi$ ausgehen. Angaben in Gradmaß müssen mit degtorad(x) umgerechnet werden.

Welche Funktionen noch alle in "Math" enthalten sind, findet man unter
http://lazarus-ccr.sourceforge.net/docs/rtl/math/

Aufgabe

1. Wirtschaft: Handwerk hat goldenen Boden
   Malermeister Klecksel muss zur Berechnung des ungefähren Verbrauchs an Farbe nach Angabe von Höhe, Breite und Länge eines Raums wissen
   a) Welche Fläche die Wände haben (Fenster spielen erst mal keine Rolle)
   b) Welche Fläche die Decke hat (wird manchmal in einer anderen Farbe gestrichen)
   Entwickle eine geeignete komfortable Software!
2. Wirtschaft: Mehrwertsteuer
   Schreibe ein Programm, das für einen eingegebenen Betrag die Mehrwertsteuer berechnet und außerdem den Betrag zuzüglich Mehrwertsteuer. Den aktuellen Mehrwertsteuersatz findet man wahrscheinlich im Internet. Der Wert sollte kaufmännisch auf zwei Nachkommastellen gerundet sein.
3. Mathematik: Lineare Funktionen
   Eine lineare Funktion hat die Funktionsgleichung $f(x)=m \cdot x + n$. Schreibe ein Programm, bei dem man m, n und x eingeben kann und den Funktionswert erhält.
4. Mathematik: Kompliziertere Funktionen
   Schreibe ein Programm, das nach der Eingabe des Wertes für den Wert des Polynoms $x^2-8x+5$ berechnet.
5. Mathematik: Geradensteigung aus zwei Punkten
   In Klasse 9 lernt man, wie man aus zwei Punkten die Steigung einer Gerade durch diese beiden Punkte berechnet.
   Schreibe ein Programm für einen Freund aus der 9. Klasse, der seine Hausaufgaben „kontrollieren“ will.
   Zur Erinnerung: $m=\frac{y_2-y_1}{x_2-x_1}$
6. Mathematik: y-Achsenabschnitt aus zwei Punkten
   Erweitere das obige Programm, das aus den zwei gegebenen Punkten auch den y-Achsenabschnitt berechnet.
7. Mathematik: Nullstellenberechnung
   Eine lineare Funktion hat die Funktionsgleichung $f(x)=m \cdot x + n$. Schreibe ein Programm, bei dem man m und n eingeben kann und das daraufhin die Nullstelle ausrechnet.
8. Mathematik: Nullstellen quadratischer Funktionen
   Du kennst die p-q-Formel (oder auch a-b-c-Formel) zum Lösen quadratischer Gleichungen. Schreibe ein Programm, das nach Eingabe von p und q (bzw. a, b und c) die beiden Nullstellen der entsprechenden Funktion berechnet. Versuche einige Eingaben und überlege, ob es nicht Eingaben geben könnte, die Probleme verursachen.
9. Physik: Pendelhöhe
   Ein Fadenpendel mit einem kleinen Pendelkörper am Ende einer Länge wird um einen bestimmten Winkel (angegeben im Gradmaß) ausgelenkt. Schreibe ein Programm, das nach Eingabe der Pendellänge und des Auslenkwinkels die Höhe des Pendelkörpers über der Ruhelage errechnet.

Lazarus-Buch

• Einführung
• Technisches
• Komponenten, Eigenschaften, Ereignisse
• Computer-Mathematik
• Verzweigungen
• Spielen mit dem Zufall
• Schleifen
• Computer-Graphik
• Geschachtelte Verzweigungen und Verzweigungen in Schleifen
• Prozeduren, Funktionen und Bibliotheken
• Felder (Arrays)
• Zeichen (Char) und Zeichenkette (String)
• Dateien
• Graphische Komponenten